Добавил QUEUE_I16, поправил AIM725_Status

2026-07-31 13:02:26 +03:00
parent a62be1c4bd
commit 5519d81c5a
3 changed files with 80 additions and 12 deletions
@@ -0,0 +1,66 @@
+(*
+===============================================================================
+ Project    : PLC_Library
+ Device     : -
+ Path       : Общие
+ Name       : QUEUE_I16
+ Type       : FUNCTION_BLOCK
+===============================================================================
+*)
+
+FUNCTION_BLOCK QUEUE_I16
+(*
+	Очередь FIFO на 16 элементов типа INT
+*)
+VAR_INPUT
+	Din : INT; (* Переменная для записи в очередь *)
+	E : BOOL := TRUE; (* Включение очереди *)
+	POP : BOOL; (* Извлечение из очереди *)
+	PUSH : BOOL; (* Добавление в очередь *)
+	RST : BOOL; (* Сброс *)
+END_VAR
+VAR_OUTPUT
+	Dout : INT; (* Значение, извлеченное из очереди *)
+	EMPTY : BOOL := TRUE;
+	FULL : BOOL;
+END_VAR
+VAR
+	queue : ARRAY[0..n] OF INT;
+	Head : INT; (* индекс чтения *)
+	Tail : INT; (* индекс записи *)
+	Count : INT; (* количество элементов *)
+END_VAR
+VAR CONSTANT
+	n : INT := 15; (* 16 элементов *)
+END_VAR
+(*----- IMPLEMENTATION -----*)
+IF RST THEN
+	Head := 0;
+	Tail := 0;
+	Count := 0;
+	EMPTY := TRUE;
+	FULL := FALSE;
+	Dout := 0;
+ELSIF E THEN
+	(* Извлечение *)
+	IF POP AND NOT EMPTY THEN
+		Dout := queue[Head];
+		Head := Head + 1;
+		IF Head > n THEN
+			Head := 0;
+		END_IF;
+		Count := Count - 1;
+	END_IF;
+	(* Добавление *)
+	IF PUSH AND NOT FULL THEN
+		queue[Tail] := Din;
+		Tail := Tail + 1;
+		IF Tail > n THEN
+			Tail := 0;
+		END_IF;
+		Count := Count + 1;
+	END_IF;
+	EMPTY := (Count = 0);
+	FULL := (Count = n + 1);
+END_IF;
+END_FUNCTION_BLOCK